Cost Minimization for a Firm

Economic concepts
Isoquant, isocost line, optimal inputs

Problem
A firm uses labor (L) and energy (E) to produce output (Q). The production function is: Q=F(L,E). The firm hires labor and buys energy in competitive factor markets. The cost of a unit of labor is w, that of a unit of energy is r. The firm's objective is to minimize the total cost of producing a given level of output(Qo).

Questions
1. What is the least-cost combination of labor and energy for the firm?
2. Sketch isoquants and isocost lines to indicate the optimal point graphically.
3. How does the firm's use of labor and energy change in response to:
- Changes in the cost of the inputs?
- A change in the desired level of output?

Data
F(L,E)=L^(3/4)E^(1/4), w=10, r=4, Qo=2000.

Steps

1. Define the production function and assign parameter values.

> restart;

> w:=15; r:=4; Q:=L^(3/4)*E^(1/4); Qo:=2000;

2. Define the cost function to be minimized.

> C:= w*L + r*E;

3. Define the Lagrangian function for the minimization problem. The Lagrange multiplier is denoted by lambda .

> lagr:= C + lambda*(Qo-Q);

4. Differentiate the Lagrangian function w.r.t L, E and lambda.

> lagr_1:=diff(lagr,L); lagr_2:=diff(lagr,E); lagr_3:=diff(lagr,lambda);

5. The first-order conditions (FOCs) for a minimum require that the three first-order derivatives be equal to zero. Solve the FOCs for the optimal values of L, E and lambda.

> soln:= evalf(solve({lagr_1=0,lagr_2=0,lagr_3=0,L>=0,E>=0},{L,E,lambda}));

6. Denote the optimal values by L_opt, E_opt and lambda_opt.

> L_opt:= evalf(subs( soln, L ));

> E_opt:= evalf(subs( soln, E ));

> lambda_opt:= evalf(subs( soln, lambda ));

7. In order to ensure that the solution obtained from the FOCs does indeed correspond to a minimum, set up the bordered Hessian matrix (H_bar) and verify that the determinant of H_bar is negative. [Note: The determinant of H_bar must be evaluated at (L_opt,E_opt,lambda_opt).]

> with(linalg):

Warning, the protected names norm and trace have been redefined and unprotected

> lagr_11:=diff(lagr_1,L);

> lagr_12:=diff(lagr_1,E);

> lagr_21:=diff(lagr_2,L);

> lagr_22:=diff(lagr_2,E);

> const_1:=diff(Q,L);

> const_2:=diff(Q,E);

> H_bar:=matrix([[0,const_1,const_2],[const_1,lagr_11,lagr_12],[const_2,lagr_21,lagr_22]]);

> H_bar_det:=det(H_bar);

> H_bar_det:=subs({L=L_opt,E=E_opt,lambda=lambda_opt},H_bar_det);

8. Obtain the minimum cost of production, C_min.

> C_min:= w*L_opt + r*E_opt;

9. Sketch the isoquant and isocost line, and show that the point of tangency between the two yields the optimal combination of L and E.

with(plots):

Warning, the name changecoords has been redefined

The isoquant represents combinations of E and L such that a particular amount of output is produced. To sketch the isoquant, obtain E in terms of L from the production function.

E1:=solve(Q=Qo,E);

The isocost line represents combinations of E and L such that the total cost is constant. Accordingly, to sketch the isocost line, set C equal to C_min in the cost function, and obtain E in terms of L.

E2:=solve(C=C_min,E);

plot({E1,E2}, L=1600..2200, E=800..3500, axes=BOXED, title=`Isoquant and Isocost line`);

>

10. In order to investigate the effects of changes in w, r, and Qo on the firm's use of labor and energy, and its minimum cost of production, alter the relevant parameter values in Step 1 and then follow Steps 2-9.

Show the following:
- An increase in the wage rate, ceteris paribus , will lead the firm to use less labor and more energy.
- An increase in the desired output level, ceteris paribus , will lead the firm to use more of both inputs.

_________
June 2000

Dr. Sanjay Paul
St. Norbert College