Economic Growth in a Neoclassical Model
Economic concepts
Capital accumulation, steady state
Problem
Consider the Solow model of economic growth. The country's output of a single good (Y) is produced according to a production function, Y=AF(K,L), where A represents the level of technology, K is capital stock and L is labor. The production function exhibits constant returns to scale. Thus, the per-capita production function may be written as y=Af(k), where k is the capital-labor ratio.
(På godt dansk: definer k(t)= K(t)/L(t) og y(t)=Y(t)/L(t) og antag, at Y(t) har en form så y(t) kan udtrykkes som funktion af k(t) alene. Se eksemplet nedenfor).
Let the production function be of the Cobb-Douglas variety:
(1) Y(t) = A * K(t)^(1/4) * L(t)^(3/4),
where Y, K and L vary with time.
The per-capita production function, in terms of the capital-labor ratio, is:
(2) y(t) = A * k(t)^(1/4)
Saving is a fixed proportion of output:
(3) S(t) = s * Y(t)
Investment equals saving:
(4) I(t) = S(t)
Population grows at a constant rate of n:
(5) dL(t)/dt = n * L(t)
The change in capital stock is given by the gross investment less depreciation:
(6) dK(t)/dt = I(t) - delta * K(t)
From equations (1)-(6), obtain the rate of change in the capital-labor ratio:
(7) dk(t)/dt = s * y(t) - ( n + delta ) * k(t)
Equation (7) is the backbone of the Solow model.
Questions
1. Describe the evolution of capital stock over time.
2. In steady state, what is the capital-labor ratio?
3. Show that the growth in capital-labor ratio declines as the economy nears steady state.
4. How is the steady-state capital-labor ratio affected by changes in the savings rate, population growth and technology?
Data
A = 27, s = 0.3, n = 0.02, delta = 0.01
Steps
1. Define the production function and assign parameter values.
> restart;
> Y:=A*K^(1/4)*L^(3/4);
> s:=0.3:
> A:=27:
> n:=0.02:
> delta:=0.01:
2. Define the per-capita production function in terms of the capital-labor ratio (k).
> y:=A*k^(1/4);
3. Obtain the rate of change of the capital-labor ratio.
> expr1:=s*y;
> expr2:=(n+delta)*k;
> dk_dt:=expr1-expr2;
4. In the steady state, the capital stock and labor force grow at the same rates, i.e, the capital-labor ratio becomes constant. Solve for the steady-state value of k and denote it by k_ss.
> soln:=solve(dk_dt,k);
> k_ss:=max(soln[1],soln[2]);
5. Plot the steady-state value of the capital-labor ratio.
> plot({expr1,expr2}, k=100..2400, axes=BOXED, title=`Capital-labor ratio`);
6. Write the differential equation governing the change in the capital-labor ratio.
> eq:=diff(k(t),t) - (s*A)*k(t)^(1/4) + (n+delta)*k(t)=0;
7. Let the initial capital-labor ratio be 1700.
> ini:=k(0)=1700;
8. Using the dsolve command for solving differential equations, obtain the time path of capital-labor ratio. Evaluate k(t) at t=0 and t=500. These, respectively, yield the inital and steady-state values of k.
> soln:= dsolve({eq,ini},{k(t)}, type=numeric);
> soln(0);
> soln(500);
9. Plot the time path of the capital-labor ratio. Note how, as t increases, the rate of change in k becomes smaller, implying that the country's growth rate falls as it approaches steady state.
> with(plots):
Warning, the name changecoords has been redefined
> odeplot(soln, [t,k(t)], 0..200, axes=BOXED, title=`Growth of k`);
>
10. In order to investigate the effects of changes in the saving rate, population growth, and technology on the capital-labor ratio, alter the requisite parameter values in Step 1 and complete Steps 2-9.
Show the following:
- An increase in s , ceteris paribus , will lead to a higher capital-labor ratio in steady state.
- An increase in n , ceteris paribus , will lead to a lower capital-labor ratio in steady state.
- An increase in A , ceteris paribus , will lead to a higher capital-labor ratio in steady state.
_____________
June 2000
Dr. Sanjay Paul
St. Norbert College
(danske kommentarer af Olav Geil)